Stxerr: Unterschied zwischen den Versionen

STXERR   CSECT
************************************************************************
*                                                                      *
*     COPYRIGHT (C) SIEMENS AG  1988                                   *
*     COPYRIGHT (C) SIEMENS NIXDORF INFORMATIONSSYSTEME AG  1991       *
*     ALL RIGHTS RESERVED                                              *
*                                                                      *
************************************************************************
*
*****************************************************************       
* AUSGABEERWEITERUNG UM R3 UND R4
** V3.0AK1
*****************************************************************       
* BEI IW48 WIRD HIER DER PC AUF SCHLEIFE GESETZT UM DEN ASYN YREC
* ZU STARTEN. DIE FEHLERHAFTE SEITE BLEIBT HALT ALS LEICHE ZURUECK.
* BEI IW<>48 WIRDS TROTZDEM DUMPEN(ODER LOOPEN)
*****************************************************************       
         PRINT NOGEN,BASE
*----------------------------------------------------------------------*
****     INIT REGISTERS                                             ****
*----------------------------------------------------------------------*
         SPACE
R0       EQU   0
R1       EQU   1
R2       EQU   2
R3       EQU   3
R4       EQU   4
R5       EQU   5
R6       EQU   6
R7       EQU   7
R8       EQU   8
R9       EQU   9
R10      EQU   10
R11      EQU   11
R12      EQU   12
R13      EQU   13
R14      EQU   14
R15      EQU   15
*---------------------------------------------------------------------*
         GPARMOD 31
STXERR   AMODE ANY
STXERR   RMODE ANY
##BAL    OPSYN ##BAS
##BALR   OPSYN ##BASR
*---------------------------------------------------------------------*
         USING *,R15
         USING USEREIN,R4
         USING STATEIN,R3
         USING STXBAS,R8
STXBAS   BASR  R8,0
         BCTR  R8,R0
         BCTR  R8,R0
         DROP  15
         B     BEGSTX
*----------------------------------------------------------------------*
***      S T X I T  -  ROUTIENE                                      ***
*----------------------------------------------------------------------*
BEGSTX   EQU   *
STXINI   EQU   *
         ST    R3,SRR3
         CONTXT SAVE=REGSAV,PROCESS=LAST
         MVC   SRRPC(4),PCOUNT
         MVC   SRR03(4),REGS3 
         MVC   SRR04(4),REGS4 
         BAS   R13,SFEHLER
         CONTXT SAVE=REGSAV,PROCESS=MAIN
         L     R1,=V(SCHLEIFE)      ASYN YREC
         ST    R1,PCOUNT
         CONTXT SAVE=REGSAV,FUNCT=WRITE,PROCESS=LAST
         EXIT
         DS    0F
REGSAV   DS    17F
         ORG   REGSAV+64
PCOUNT   DS    F
         ORG   REGSAV+12
REGS3    DS    F
         ORG   REGSAV+16
REGS4    DS    F
         ORG
*----------------------------------------------------------------------*
         DS    F
SFEHLER  EQU   *
         ST    R13,SFEHLER-4
         UNPK  SRRRIW,SRR3(5)
         TR    SRRRIW,SX-240
         MVI   SRRRIW+8,C' '
* R15
         UNPK  SRRR15,SRRPC(5)
         TR    SRRR15,SX-240
         MVI   SRRR15+8,C' '
* R3
         UNPK  SRRR03,SRR03(5)
         TR    SRRR03,SX-240
         MVI   SRRR03+8,C' '
* R4
         UNPK  SRRR04,SRR04(5)
         TR    SRRR04,SX-240
         MVI   SRRR04+8,C' '
         WROUT SRRMSG,STERME
STERME   L     R13,SFEHLER-4
         BR    R13
*----------------------------------------------------------------------*
SRR3     DS    F
SRRPC    DS    F
SRR03    DS    F
SRR04    DS    F
SRRMSG   DC    Y(SRRMSGE-SRRMSG)
         DC    C'   %  ZCP0006 CP-ERROR AT:'
SRRTEXT  DC    CL20'STXIT/ERROR'
         DC    C'  PC:'
SRRR15   DS    L9
         DC    C'  IW:'
SRRRIW   DS    L9
         DC    C'  R3:'
SRRR03   DS    L9
         DC    C'  R4:'
SRRR04   DS    L9
SRRMSGE  EQU   *-1
         ORG
         DS    CL200
         DS    0F
SX       DC    C'0123456789ABCDEF'
*---------------------------------------------------------------------*
***      D S E C T S                                                ***
*---------------------------------------------------------------------*
*----    ZENTRALE TABELLEN  ------------------------------------------*
         STATEIN
         EJECT
         USEREIN
*---------------------------------------------------------------------*
         END