Cpsysfl

CPSYSFL  CSECT
************************************************************************
*                                                                      *
*     COPYRIGHT (C) SIEMENS AG  1988                                   *
*     COPYRIGHT (C) SIEMENS NIXDORF INFORMATIONSSYSTEME AG  1991       *
*     ALL RIGHTS RESERVED                                              *
*                                                                      *
************************************************************************
*
* NAMENSAENDERUNG CP.SYSOUT. --> SYSLOG.CP.030 .
** V3.0A00
         PRINT GEN,BASE
*----------------------------------------------------------------------*
****     INIT REGISTERS                                             ****
*----------------------------------------------------------------------*
         SPACE
R0       EQU   0
R1       EQU   1
R2       EQU   2
R3       EQU   3
R4       EQU   4
R5       EQU   5
R6       EQU   6
R7       EQU   7
R8       EQU   8
R9       EQU   9
R10      EQU   10
R11      EQU   11
R12      EQU   12
R13      EQU   13
R14      EQU   14
R15      EQU   15
*---------------------------------------------------------------------*
         GPARMOD 31
CPSYSFL  AMODE ANY
CPSYSFL  RMODE ANY
##BAL    OPSYN ##BAS
##BALR   OPSYN ##BASR
*---------------------------------------------------------------------*
         USING *,R15
         STM   R8,R12,SAVTAB
         ST    R14,SAV14
         SPACE
         USING CPSYSFLA,R3,R4
CPSYSFLA BASR  R3,0
         BCTR  R3,R0
         BCTR  R3,R0
         LA    R1,4095
         LA    R4,1(R3,R1)
         DROP  15
         B     BEG
SAV14    DS    F
SAVTAB   DS    5F
*---------------------------------------------------------------------*
         DS    0F
BEG      EQU   *
         CLI   SYSLOGD,C'X'
         BE    SYSLOG1
         SYSFL 'SYSOUT=(PRIMARY)'
         MVC   SYSLT1+63(20),SYSLOGD
         CNOP  0,4
SYSLT1   CMD   'TYPE',' %  ZCP0017 SYSLOG.CP.030.XX.XX.XX.XXXXXX.XXXX C-
               LOSED.'
SYSLOG1  GDATE LOGDAT,FORMAT=ISO,TOD=LOGTIM
         TMODE PARLIST=TMODPL       (MAKRO DTMODE)
         MVC   SYSLOGD(2),LOGDAT
         MVC   SYSLOGD+3(2),LOGDAT+3
         MVC   SYSLOGD+6(2),LOGDAT+6
         MVC   SYSLOGD+9(2),LOGTIM
         MVC   SYSLOGD+11(2),LOGTIM+3
         MVC   SYSLOGD+13(2),LOGTIM+6
         MVC   SYSLOGD+16(4),TMODTSN
         MVC   SYSLOGO+61(20),SYSLOGD
         CNOP  0,4
SYSLOGO  SYSFL 'SYSOUT=SYSLOG.CP.030.XX.XX.XX.XXXXXX.XXXX'
         LTR   R15,R15
         BNZ   SYSLERR
         MVC   SYSLT2+63(20),SYSLOGD
         CNOP  0,4
SYSLT2   CMD   'TYPE',' %  ZCP0018 SYSLOG.CP.030.XX.XX.XX.XXXXXX.XXXX O-
               PENED.'
         B     SYSLOGE
SYSLERR  EQU   *
         CMD   'TYPE',' %  ZCP0019 ERROR ON ''SYSFILE SYSOUT'' COMMAND'
SYSLOGE  EQU   *
RETCO    EQU   *
         LM    R8,R12,SAVTAB
         L     R14,SAV14
         BR    R14
*----------------------------------------------------------------------*
         DS    0F
LOGDAT   DS    CL12
LOGTIM   DS    CL8
SYSLOGD  DC    C'XX.XX.XX.XXXXXX.XXXX'
         DS    0F
*---------------------------------------------------------------------*
*        E X T R N   S   /  E N T R I E S
*---------------------------------------------------------------------*
         ENTRY SYSLOGD      KOORD. MIT CPADMIN
*---------------------------------------------------------------------*
         DTMODE DSECT=NO
*
         END